In this section, we will learn how to interface our Arduino board with different sensors. We will discuss the following sensors −

• Humidity sensor (DHT22)
• Temperature sensor (LM35)
• Water detector sensor (Simple Water Trigger)
• PIR SENSOR
• ULTRASONIC SENSOR
• GPS

Humidity Sensor (DHT22)

The DHT-22 (also named as AM2302) is a digital-output, relative humidity, and temperature sensor. It uses a capacitive humidity sensor and a thermistor to measure the surrounding air, and sends a digital signal on the data pin.

In this example, you will learn how to use this sensor with Arduino UNO. The room temperature and humidity will be printed to the serial monitor.

The DHT-22 Sensor

The connections are simple. The first pin on the left to 3-5V power, the second pin to the data input pin and the right-most pin to the ground.

Technical Details

• Power − 3-5V

• Max Current − 2.5mA

• Humidity − 0-100%, 2-5% accuracy

• Temperature − 40 to 80°C, ±0.5°C accuracy

Components Required

You will need the following components −

• 1 × Breadboard
• 1 × Arduino Uno R3
• 1 × DHT22
• 1 × 10K ohm resistor

Procedure

Follow the circuit diagram and hook up the components on the breadboard as shown in the image below.

Sketch

Open the Arduino IDE software on your computer. Coding in the Arduino language will control your circuit. Open a new sketch File by clicking New.

Arduino Code

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we''re connected to
// Uncomment whatever type you''re using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *Ft");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

Code to Note

DHT22 sensor has four terminals (V_cc, DATA, NC, GND), which are connected to the board as follows −

• DATA pin to Arduino pin number 2
• V_cc pin to 5 volt of Arduino board
• GND pin to the ground of Arduino board
• We need to connect 10k ohm resistor (pull up resistor) between the DATA and the V_cc pin

Once hardware connections are done, you need to add DHT22 library to your Arduino library file as described earlier.

Result

You will see the temperature and humidity display on serial port monitor which is updated every 2 seconds.